Resolved: Module vpn s2s terraform - is tuple with 2 element

In this post, we will see how to resolve Module vpn s2s terraform – is tuple with 2 element

Question:

I have in main.tf

module "vpn_s2s" {
  source     = "../../../modules/vpc/vpn"
  depends_on = [module.vpc]

  vpn_gateway_id = module.vpc.vpn_gateway_id

  vpn_s2s = {
    "def1" = {
      "vpn_ip_address" = "8.8.8.8"
      "vpn_cidr"       = ["1.1.1.1/32","2.2.2.2/32"]
    }
  }
}

And in module main.tf

resource "aws_vpn_connection_route" "vpn_route" {
  for_each = var.vpn_s2s

  destination_cidr_block = each.value.vpn_cidr
  vpn_connection_id      = aws_vpn_connection.vpn_connection[each.key].id
}

variables.tf
variable "vpn_s2s" { type = map(any) }
variable "vpn_gateway_id" { type = string }

But i get

     │ each.value.vpn_cidr is tuple with 2 elements
│ 
│ Inappropriate value for attribute "destination_cidr_block": string required.

I try toset, flatter
but i still don’t know how to solve this problem.
Any ideas?

Best Answer:

You have nested list in a map. You need to flatten your variable to iterate over it:

locals {
  flat_vpn_s2s = merge([
    for id, vpn in var.vpn_s2s: {
      for cidr in vpn.vpn_cidr:
        "${id}-${cidr}" => {
            vpn_name = id
            vpn_cidr = cidr
            vpn_ip_address = vpn.vpn_ip_address
         }
    }
    ]...) # please do NOT remove the dots.
}

then

resource "aws_vpn_connection_route" "vpn_route" {
  for_each = local.flat_vpn_s2s

  destination_cidr_block = each.value.vpn_cidr
  vpn_connection_id      = aws_vpn_connection.vpn_connection[each.value.vpn_name].id
}

If you have better answer, please add a comment about this, thank you!

Source: Stackoverflow.com

Resolved: Module vpn s2s terraform – is tuple with 2 element

Question:

Best Answer:

Related